//+------------------------------------------------------------------+
//| CustomSymbolSetSessionQuote.mq5 |
//| Copyright 2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#define CUSTOM_SYMBOL_NAME Symbol()+".C" // özel sembol adı
#define CUSTOM_SYMBOL_PATH "Forex" // sembolün oluşturulacağı grubun adı
#define CUSTOM_SYMBOL_ORIGIN Symbol() // özel sembolün temel alınacağı sembolün adı
#define SESSION_0_FROM D'1970.01.01 00:15:00' // 0 oturumu başlangıç saati
#define SESSION_0_TO D'1970.01.01 11:59:00' // 0 oturumu bitiş saati
#define SESSION_1_FROM D'1970.01.01 12:15:00' // 1 oturumu başlangıç saati
#define SESSION_1_TO D'1970.01.01 23:59:00' // 1 oturumu bitiş saati
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- özel sembol oluştururken hata kodunu al
int create=CreateCustomSymbol(CUSTOM_SYMBOL_NAME, CUSTOM_SYMBOL_PATH, CUSTOM_SYMBOL_ORIGIN);
//--- hata kodu 0 değilse (başarılı sembol oluşturma) ve 5304 değilse (sembol zaten oluşturulmuş) - bırak
if(create!=0 && create!=5304)
return;
//--- baz sembol ve oturum indeksiyle birlikte başlığı yazdır ve
//--- pazartesiden cumaya kadar haftanın günlerine göre bir döngü içinde, her kotasyon oturumunun başlangıç ve bitiş saatlerini günlüğe yazdır
for(int session=0; session<2; session++)
{
PrintFormat("Quote session %d of '%s' symbol from which the custom '%s' was created", session, CUSTOM_SYMBOL_ORIGIN, CUSTOM_SYMBOL_NAME);
for(int day_of_week=MONDAY; day_of_week<SATURDAY; day_of_week++)
SymbolInfoSessionQuotePrint(CUSTOM_SYMBOL_ORIGIN, (ENUM_DAY_OF_WEEK)day_of_week, session);
}
//--- iki oturuma göre bir döngü içinde
bool res=true;
for(int session=0; session<2; session++)
{
datetime from = SESSION_0_FROM;
datetime to = SESSION_0_TO;
if(session>0)
{
from = SESSION_1_FROM;
to = SESSION_1_TO;
}
//--- haftanın her günü olmak üzere özel sembol için kotasyon oturumları zamanını ayarla
ResetLastError();
for(int day_of_week=MONDAY; day_of_week<SATURDAY; day_of_week++)
res &=CustomSymbolSetSessionQuote(CUSTOM_SYMBOL_NAME, (ENUM_DAY_OF_WEEK)day_of_week, session, from, to);
}
//--- oturumlardan herhangi birini ayarlarken bir hata oluştuysa, günlükte ilgili bir mesaj görüntüle
if(!res)
Print("CustomSymbolSetSessionQuote() failed. Error ", GetLastError());
//--- özel sembol ve oturum indeksiyle birlikte başlığı yazdır ve
//--- pazartesiden cumaya kadar haftanın günlerine göre bir döngü içinde, her kotasyon oturumunun başlangıç ve bitiş saatlerini günlüğe yazdır
for(int session=0; session<2; session++)
{
PrintFormat("Quote session %d of custom symbol '%s' based on '%s'", session, CUSTOM_SYMBOL_NAME, CUSTOM_SYMBOL_ORIGIN);
for(int day_of_week=MONDAY; day_of_week<SATURDAY; day_of_week++)
SymbolInfoSessionQuotePrint(CUSTOM_SYMBOL_NAME, (ENUM_DAY_OF_WEEK)day_of_week, session);
}
//--- grafikte yorum olarak kod sonlandırma tuşları hakkında bir ipucu görüntüle
Comment(StringFormat("Press 'Esc' to exit or 'Del' to delete the '%s' symbol and exit", CUSTOM_SYMBOL_NAME));
//--- sonsuz bir döngüde çıkmak için Esc veya Del tuşlarına basılmasını bekle
while(!IsStopped() && TerminalInfoInteger(TERMINAL_KEYSTATE_ESCAPE)==0)
{
Sleep(16);
//--- Del tuşuna basıldığında, oluşturulan özel sembolü sil
if(TerminalInfoInteger(TERMINAL_KEYSTATE_DELETE)<0)
{
if(DeleteCustomSymbol(CUSTOM_SYMBOL_NAME))
PrintFormat("Custom symbol '%s' deleted successfully", CUSTOM_SYMBOL_NAME);
break;
}
}
//--- çıkmadan önce grafiği temizle
Comment("");
/*
sonuç:
Quote session 0 of 'EURUSD' symbol from which the custom 'EURUSD.C' was created
- Monday 00:15 - 23:55
- Tuesday 00:15 - 23:55
- Wednesday 00:15 - 23:55
- Thursday 00:15 - 23:55
- Friday 00:15 - 23:55
Quote session 1 of 'EURUSD' symbol from which the custom 'EURUSD.C' was created
- Monday Session not set
- Tuesday Session not set
- Wednesday Session not set
- Thursday Session not set
- Friday Session not set
Quote session 0 of custom symbol 'EURUSD.C' based on 'EURUSD'
- Monday 00:15 - 11:59
- Tuesday 00:15 - 11:59
- Wednesday 00:15 - 11:59
- Thursday 00:15 - 11:59
- Friday 00:15 - 11:59
Quote session 1 of custom symbol 'EURUSD.C' based on 'EURUSD'
- Monday 12:15 - 23:59
- Tuesday 12:15 - 23:59
- Wednesday 12:15 - 23:59
- Thursday 12:15 - 23:59
- Friday 12:15 - 23:59
*/
}
//+------------------------------------------------------------------+
//| Özel sembol oluştur, bir hata kodu geri döndür |
//+------------------------------------------------------------------+
int CreateCustomSymbol(const string symbol_name, const string symbol_path, const string symbol_origin=NULL)
{
//--- özel sembolün temel alınacağı sembolün adını tanımla
string origin=(symbol_origin==NULL ? Symbol() : symbol_origin);
//--- özel bir sembol oluşturulamadıysa ve bu hata 5304 değilse, bunu günlükte raporla
ResetLastError();
int error=0;
if(!CustomSymbolCreate(symbol_name, symbol_path, origin))
{
error=GetLastError();
if(error!=5304)
PrintFormat("CustomSymbolCreate(%s, %s, %s) failed. Error %d", symbol_name, symbol_path, origin, error);
}
//--- başarılı
return(error);
}
//+------------------------------------------------------------------+
//| Özel sembol kaldır |
//+------------------------------------------------------------------+
bool DeleteCustomSymbol(const string symbol_name)
{
//--- sembolü Piyasa Gözlemi penceresinden gizle
ResetLastError();
if(!SymbolSelect(symbol_name, false))
{
PrintFormat("SymbolSelect(%s, false) failed. Error %d", GetLastError());
return(false);
}
//--- özel sembol silinemediyse, bunu günlükte raporla ve 'false' geri döndür
ResetLastError();
if(!CustomSymbolDelete(symbol_name))
{
PrintFormat("CustomSymbolDelete(%s) failed. Error %d", symbol_name, GetLastError());
return(false);
}
//--- başarılı
return(true);
}
//+------------------------------------------------------------------+
//| Belirtilen sembol ve haftanın günü için belirtilen kotasyon |
//| seansının başlangıç ve bitiş saatlerini günlüğe gönder |
//+------------------------------------------------------------------+
void SymbolInfoSessionQuotePrint(const string symbol, const ENUM_DAY_OF_WEEK day_of_week, const uint session_index)
{
//--- kotasyon oturumunun başlangıcını ve sonunu kaydetmek için değişkenler bildir
datetime date_from; // oturum başlangıç saati
datetime date_to; // oturum bitiş saati
//--- numaralandırma sabitinden gün adını oluştur
string week_day=EnumToString(day_of_week);
if(week_day.Lower())
week_day.SetChar(0, ushort(week_day.GetChar(0)-32));
//--- kotasyon seansından sembol ve haftanın gününe göre veri al
if(!SymbolInfoSessionQuote(symbol, day_of_week, session_index, date_from, date_to))
{
int err=GetLastError();
string message=(err==4307 ? StringFormat("- %-10s Session not set", week_day) :
StringFormat("SymbolInfoSessionQuote(%s, %s, session %d) failed. Error %d", symbol, week_day, session_index, GetLastError()));
Print(message);
return;
}
//--- belirtilen kotasyon oturumu için verileri günlüğe gönder
PrintFormat("- %-10s %s - %s", week_day, TimeToString(date_from, TIME_MINUTES), TimeToString(date_to, TIME_MINUTES));
}
|